Juan Ferrer and Jorge Cases built a liquid tester, with only two wires and a resistor, which can measure the resistance of a liquid. Because every liquid has a different resistance you can separate different drinks like water or orange juice. With some Processing code you can do something nice with those values.

How to make your own liquid tester:
You need an Arduino, some wires and a 10K resistor.
Upload the standardFirmata to the Arduino, read this for more info.

// Detector de Liquidos (Liquid Detector)
// By Juan Ferrer and Jorge Cases
// open this file in Processing and upload the Standard Firmata to your Arduino
// connect the wires to the analog input port number 0

import processing.serial.*;
import cc.arduino.*;

Arduino arduino;

color off = color(4, 79, 111);
color on = color(84, 145, 158);

color blueColor = color(0,0,250);
color orangeColor = color(255,128,0);

int heightVal = 280;
int widthVal = 470;
int adjust = 20;
PFont fontA;

void drawGraph() {
  line(adjust,adjust,adjust,heightVal-(adjust*2));
  line(adjust,heightVal-(adjust*2),widthVal-(adjust*2),heightVal-(adjust*2));
}

void setup() {
  size(widthVal, heightVal);
  arduino = new Arduino(this, Arduino.list()[0], 115200);
  fontA = loadFont("CourierNew36.vlw");
  textFont(fontA, 32);
}

void draw() {
  background(off);
  stroke(on);

  drawGraph();
  int value = arduino.analogRead(0);

  if (value < 980 && value > 900) {
    fill(blueColor);
    text("this is water", 200, 90);
  } else if (value<800 && value > 700) {
    fill(orangeColor);
    text("this is orange juice", 200, 90);
  }
  else {
    fill(off);
    text("", 200, 90);
  }
  println(value);
  rect(adjust,heightVal-(adjust*2),50,-(heightVal-(adjust*2))*value/1024);
  delay(500);
}

download processing.org code

After @BarackObama, @BritneySpears and @oprah it is now time for the coffeemachine to get on Twitter and add some meaning full words.

What does it do?

It will tweet “the coffee machine says: I’m making coffee” if you turn on the coffeemachine, if you switch it off it will tweet “the coffee machine says: someone switched me off”.

How does it work?

This is an overview of the hardware/software/services I used:
Sensor > Arduino > Processing > PHP > Twitter

A LDR (light dependent resistor) is glued on the on/off led of the coffeemachine. When the coffeemachine is switched on the led turns on, the ldr detects this light. This LDR is connected to an Arduino microcontroller, Processing reads the value from the Arduino using Firmata and Processing sends this to a php file which will send it to Twitter.

How to build your own?

Although it looks a bit overwhelming it is very easy to build your own tweeting ‘whatever’ thing, All hardware, software and scripts I used to build this are opensource. I just hacked everything together.
You will need the following:

• Arduino board + software
• LDR (or an other analog sensor)
• Processing (Processing.org)
• webhosting with php support
• a Twitter account

Source files:

» Download Processing code + PHP source files

What do I need to do to get this working on my computer?

I use the Arduino Library for Processing and the Firmata firmware for the Arduino (included in Arduino 12 or higher).

1) Unzip the file ‘processing-arduino2.zip’ and copy the “arduino” folder into the “libraries” sub-folder of your Processing Sketchbook. (You can find the location of your Sketchbook by opening the Processing Preferences. If you haven’t made a “libraries” sub-folder, create one.)

2) Start the Arduino application and open the Examples > Library-Firmata > StandardFirmata sketch, and upload it to the Arduino board.

3) Upload the php files on your (php enabled) server in a folder called ‘twittertest’ (for example)
Open the file ‘coffeemachine_processing.pde’ with Processing, and edit the following lines:
- change the variable:
twitterPassword = "yourTwitterPassword";
- change the portnumber for the Arduino:
arduino = new Arduino(this, Arduino.list()[2]);
- change the url:
new URL("http://www.yourdomain.com/twittertest/insertTwitterMsg.php?pass="+twitterPassword+"&msg="+msg).openStream();

4) Open the file ‘insertTwitterMsg.php’ with a text editor and change the variable ‘$twitterUsername’ in your Twitter username.?

5) Open the file ‘ coffeemachine_processing.pde’ in Processing and press ‘run’. Now you should have your own Tweeting arduino sensor.

Instead of a coffeemachine there are hundreds of other possibilities, you can connect almost every sensor or object to Twitter, and build your own ‘internet of things’.
Next week I will post a ‘Who’s at the Office’ Processing script that scans computernames in a local network, so stay tuned…

The Processing source file ‘coffeemachine_processing.pde’:

/*
coffeemachineProcessing - receives Arduino input from sensor and sends a message to Twitter
Date: 05-2009
Copyleft by Eric Holm 

http://ericholm.nl/blog

*/

// import the Serial port library
import processing.serial.*;
// import the firmata arduino library
import cc.arduino.*;

Arduino arduino;
int sensorPin = 0;    // Analog input pin
int sensorValue = 0;  // value read from analog input
Boolean isBusy = false;
String twitterPassword;

void setup() {
  // CHANGE YOUR TWITTER PASSWORD
  twitterPassword = "yourTwitterPassword";

  // CHANGE YOUR PORT NUMBER
  arduino = new Arduino(this, Arduino.list()[2]); // v2
  arduino.pinMode(sensorPin, Arduino.INPUT);
}

void draw() {
  sensorValue = arduino.analogRead(sensorPin); // read the analog value
  // if the analog value is below a certain value
  if (sensorValue < 930) {
    switchCoffee(true);
  }
  // if the analog value is above a certain value
  if (sensorValue > 800) {
    switchCoffee(false);
  }
  // for testing the value
  println(sensorValue);
  // delay for 5 seconds
  delay(5000);
} 

public void switchCoffee(Boolean switchState){
  if (switchState) {
    if (isBusy == false) {
      // switch on the led on port 13 of the arduino
      arduino.digitalWrite(13, Arduino.HIGH);
      // for testing inside the Processing IDE
      println("the coffee machine says: I'm making coffee");
      sendToTwitter("I%20am%20making%20coffee");
      isBusy = true;
    }
  } else {
  if (isBusy == true) {
     // switch on the led on port 13 of the arduino
     arduino.digitalWrite(13, Arduino.LOW);
     // for testing inside the Processing IDE
     println("the coffee machine says: someone switched me off");
     sendToTwitter("someone%20switched%20me%20off");
     isBusy = false;
    }
  }
}

public void sendToTwitter(String msg){
  try {
    // calls the PHP script on your own domain with the 'msg' string as a parameter
    new URL("http://www.yourdomain.com/twittertest/insertTwitterMsg.php?pass="+twitterPassword+"&msg="+msg).openStream();
    // wait 3 seconds..
    delay(3000);
  }
  catch (Exception theException) {
    theException.printStackTrace();
  }
}

Presentation files: Arduino Introduction (pdf, 0,4 MB)

I also showed a demo of my pong with the Arduino and an accelerometer,
not really a replacement for the wii controller, but it’s a start

For the geeks:
I used a 2-axis digital accelerometer called “adxl202 JQC” from Analog Device. For reading the sensor I slighty modified the standard “accelerometer_memsic2125″ code.

For communicating between the Arduino and flash I used the SerialServer from Dan O’Sullivan. It’s not really simple to setup but once its working it works great.

for more information about Arduino check the ‘official’ Arduino site with a lot of tutorials and examples, and a very usefull forum.